XML.nodeValue

Доступность

Flash Player 5.

Синтаксис

my_xml.nodeValue:Node

Описание

Свойство; значение узла в XML дереве. Если XML узел является текстовым, то есть свойство nodeType равно 3, свойство nodeValue равно тексту узла. Если XML узел является XML элементом (свойство nodeType равно 1), nodeValue равно null и доступно только для чтения.

Пример

В примере ниже создаются узел-элемент и текстовый узел и проверяется свойство node value в каждом случае:

// Создаем XML документ
var doc:XML = new XML();

// Создаем XML узел, используя createElement()
var myNode:XMLNode = doc.createElement("rootNode");

// Помещаем новый узел в XML дерево
doc.appendChild(myNode);

// Создаем текстовый XML узел, используя createTextNode()
var myTextNode:XMLNode = doc.createTextNode("myTextNode");

// Помещаем новый узел в XML дерево
myNode.appendChild(myTextNode);

trace(myNode.nodeValue);
trace(myTextNode.nodeValue);

/*
Выведет:
null
myTextNode
*/

В примере ниже создается и обрабатывается анализатором XML текст. Код обходит каждый дочерний узел и отображает значение свойства node value, используя свойства firstChild и firstChild.nodeValue. При использовании firstChild для отображения содержимого узла, он содержит сущность &. Однако при использовании nodeValue, сущность заменяется символом амперсанда (&).

var my_xml:XML = new XML("<login><username>morton</username>
<password>good&amp;evil</password></login>");
trace("Используем firstChild:");
for (var i = 0; i<my_xml.firstChild.childNodes.length; i++) {
  trace("\t"+my_xml.firstChild.childNodes[i].firstChild);
}
trace("");
trace("Используем firstChild.nodeValue:");
for (var i = 0; i<my_xml.firstChild.childNodes.length; i++) {
  trace("\t"+my_xml.firstChild.childNodes[i].firstChild.nodeValue);
}

На панель Output выведется:

Используем firstChild:
  morton
  good&amp;evil

Используем firstChild.nodeValue:
  morton
  good&evil

См. также

XML.nodeType

Смотреть комментарии LiveDocs

Предыдущая | Следующая | Оглавление